'***********************************************************************
'* Response of a 1dof Mass-Spring System with damping to a sinusoidal  *
'* input force                                                         *
'* ------------------------------------------------------------------- *
'* Main Variables:                                                     *
'*                  M: Mass                                            *
'*                  K: Stiffness                                       *
'*                  C: Viscous Damping Coefficient                     *
'*                  E: Structural Damping Coefficient                  *
'*                 F0: Input Force                                     *
'* ------------------------------------------------------------------- *
'* SAMPLE RUN:                                                         *
'*                                                                     *
'*  Mass M..... = 50                                                   *
'*  Stiffness K = 1e6                                                  * 
'*  Force F0... = 10000                                                *
'*                                                                     *
'*  (V)iscous or (S)tructural Damping: S                               *
'*                                                                     *
'*  Structural damping factor: 0.05                                    * 
'*                                                                     *
'*  Frequency Scanning                                                 *
'*                                                                     *
'*  Resonance Frequency of undamped system = 22.508                    *
'*                                                                     *
'*  Starting frequency = 20                                            *
'*  Ending frequency...= 25                                            *
'*  Frequency step.....= 0.25                                          *
'*                                                                     *
'* Frequency   Displacement   Phase (deg)                              *
'* --------------------------------------                              *
'*  20.00      0.046234       13.366013                                *
'*  20.25      0.050756       14.701446                                *
'*  20.50      0.056293       16.347699                                *
'*  20.75      0.063206       18.423074                                *
'*  21.00      0.072037       21.111461                                *
'*  21.25      0.083609       24.711299                                *
'*  21.50      0.099181       29.729354                                *
'*  21.75      0.120525       37.058260                                *
'*  22.00      0.149218       48.252814                                *
'*  22.25      0.181993       65.500492                                *
'*  22.50      0.199980       89.194985                                *
'*  22.75      0.183564      -66.609176                                *
'*  23.00      0.149839      -48.520651                                *
'*  23.25      0.119585      -36.721514                                *
'*  23.50      0.097048      -29.028193                                *
'*  23.75      0.080680      -23.790753                                *
'*  24.00      0.068578      -20.053143                                *
'*  24.25      0.059388      -17.273961                                *
'*  24.50      0.052222      -15.136029                                *
'*  24.75      0.046502      -13.444959                                *
'*  25.00      0.041843      -12.076311                                *
'*                                                                     *
'* ------------------------------------------------------------------- *
'* REFERENCE: "Mecanique des vibrations lineaires By M. Lalanne,       *
'*             P. Berthier, J. Der Hagopian, Masson, Paris 1980" [16]. *
'*                                                                     *
'*                          Quick Basic Release By J-P Moreau, Paris.  *
'***********************************************************************
'Program SIN1DOF

DEFDBL A-H, O-Z
DEFINT I-N

DIM M AS DOUBLE
DIM K AS DOUBLE
DIM C2 AS INTEGER
DIM I1 AS DOUBLE
DIM M1 AS DOUBLE

PI = 3.1415926535#

CLS
PRINT
INPUT " Mass M = ", M
INPUT " Stiffness K = ", K
INPUT " Force F = ", F0
PRINT

380 INPUT " (V)iscous or (S)tructural Damping: ", B$
IF B$ = "V" THEN 450
IF B$ = "S" THEN 500
GOTO 380

450 PRINT
INPUT " Viscous damping coefficient C = ", C
C2 = 1
GOTO 540

500 PRINT
INPUT " Structural damping factor: ", E
C2 = 2

540 PRINT
PRINT " Frequency Scanning"
PRINT
F4 = 1# / 2# / PI * SQR(K / M)
PRINT USING " Resonanve Frequency of undamped system = ###.### Hz."; F4
PRINT
INPUT " Starting frequency = ", F1
INPUT " Ending frequency...= ", F2
INPUT " Frequency step.....= ", F3

F = F1

CLS
PRINT
PRINT " Frequency   Displacement   Phase (deg) "
PRINT " -------------------------------------- "

940 W = 2 * PI * F
IF C2 = 2 THEN 1010
D = (K - M * W * W) ^ 2 + (C * W) ^ 2
O1 = (K - M * W * W) / D ^ .5
I1 = C * W / D ^ .5
M1 = F0 / SQR(D)
GOTO 1050
1010 D = (K - M * W * W) ^ 2 + (E * K) ^ 2
O1 = (K - M * W * W) / D ^ .5
I1 = E * K / D ^ .5
M1 = F0 / SQR(D)

1050 IF M1 <> 0 THEN GOTO 1140
T1 = 0
GOTO 1180
1140 IF O1 = -1 THEN
  T1 = PI
  GOTO 1180
END IF
IF O1 = 1 THEN
  T1 = 0
  GOTO 1180
END IF

IF I1 < 0 THEN GOTO 1170
'T1 = ACOS(O1)
T1 = ATN(SQR(1 - O1 ^ 2) / O1)
GOTO 1180
1170 T1 = 2 * PI - ATN(SQR(1 - O1 ^ 2) / O1)
1180 T3 = T1 / PI * 180


PRINT USING " ###.##"; F;
PRINT USING "    ###.######"; M1;
PRINT "  ";
PRINT USING "    ###.######"; T3
F = F + F3
IF F <= F2 THEN 940

END

'end of file 1dof01.bas