'**************************************************************************
'*          Encoding an ASCII text using a random encoding table          *
'* ---------------------------------------------------------------------- *
'* The text to encode is in file codage.dat.                              *
'* The random encoding table is in file code.lst.                         *
'* The output encoded text is in file codage.lst.                         *
'*                                                                        *
'* The text can be decoded by  decodage.exe that must have access to      *
'* code.lst and codage.lst files.                                         *
'* ---------------------------------------------------------------------- *
'* SAMPLE RUN:                                                            *
'* File codage.dat contains:                                              *
'*                                                                        *
'* Program ASCII;                                                         *
'* Uses WincrtMy;                                                         *
'*                                                                        *
'* VAR                                                                    *
'*     i: word;                                                           *
'*                                                                        *
'* BEGIN                                                                  *
'*   for i:=160 to 255 do                                                 *
'*     write(i:4,' ',chr(i));                                             *
'*   Readkey;                                                             *
'*   DoneWinCrt                                                           *
'* END.                                                                   *
'*                                                                        *
'* The output file code.lst contains:                                     *
'*                                                                        *
'* t!="1#h$y%X&''<(Q)?*W+7,g-Y.s/c061;2K3/425F6i758E9@:.;}<L=!>0?w@(ATBHC *
'* uDpE[FZGRHVInJkK#LfMaNGOJP+QvR]S\TAUrVIWeXOY>Z4["\$]j^B_l`8amb{c,dSe|f *
'* %gUhxi*jMkDl_mzndoop9q&r`s3t-uNv~wqxCy:z^{)|P}b~                       *
'*                                                                        *
'* (! is coded t, " is coded =, # is coded 1, etc.)                       *
'*                                                                        *
'* The output file codage.lst contains;                                   *
'*                                                                        *
'* J&d%&8_ (]HVV.                                                         *
'* A`S` Ixz{&3fC.                                                         *
'*                                                                        *
'* r(v                                                                    *
'*     x@ ~d&,.                                                           *
'*                                                                        *
'* TpZVa                                                                  *
'*   |d& x@L6Fc 3d ;22 ,d                                                 *
'*     ~&x3S<x@/7' '7{U&<xQQ.                                             *
'*   vS8,MSC.                                                             *
'*   udzSIxzH&3                                                           *
'* pauY                                                                   *
'*                                                                        *
'*                                   Basic Release By J-P Moreau, Paris.  *
'*                                           (www.jpmoreau.fr)            *
'**************************************************************************
'Program Codage

DEFINT I-N

CONST MINCAR = 33                   'ASCII characters from 33 to 126 only
CONST MAXCAR = 126

DIM A$(MAXCAR), Z$(MAXCAR)
DIM alea AS INTEGER
DIM fait AS INTEGER

' open text files
  OPEN "codage.dat" FOR INPUT AS #1
  OPEN "codage.lst" FOR OUTPUT AS #2
  OPEN "code.lst" FOR OUTPUT AS #3

  FOR i = MINCAR TO MAXCAR
    A$(i) = CHR$(i)
  NEXT i
  
' generate a random encoding table
  alea = RND(1) * (MAXCAR - MINCAR + 1)

  Z$(MINCAR) = CHR$(MINCAR + alea)
  FOR i = MINCAR + 1 TO MAXCAR
    fait = 0
    WHILE (fait = 0)
      alea = RND(1) * (MAXCAR - MINCAR + 1)
      Z$(i) = CHR$(MINCAR + alea)
      fait = 1
      FOR j = MINCAR TO i - 1
	IF Z$(j) = Z$(i) THEN fait = 0
      NEXT j
    WEND
  NEXT i

' encode input text line by line and save
10 LINE INPUT #1, ligne$
     codee$ = ligne$
     FOR i = 1 TO LEN(ligne$)
       FOR j = MINCAR TO MAXCAR
	 IF MID$(ligne$, i, 1) = A$(j) THEN
	   IF i = 1 THEN
	     codee$ = Z$(j) + RIGHT$(codee$, LEN(codee$) - i)
	   ELSEIF i = LEN(codee$) THEN
	     codee$ = LEFT$(codee$, i - 1) + Z$(j)
	   ELSE
	     codee$ = LEFT$(codee$, i - 1) + Z$(j) + RIGHT$(codee$, LEN(codee$) - i)
	   END IF
	 END IF
       NEXT j
     NEXT i
     PRINT #2, codee$
     IF EOF(1) <> -1 THEN GOTO 10
  CLOSE #1
  PRINT #2,
  CLOSE #2

' Print random encoding table in file code.lst
  FOR i = MINCAR TO MAXCAR
    PRINT #3, Z$(i); A$(i);
    IF ((i - MINCAR + 1) MOD 35) = 0 THEN PRINT #3,
  NEXT i
  PRINT #3,
  CLOSE #3

  CLS
  PRINT
  PRINT " Program terminated. Results in file codage.lst"
  PRINT

END

' end of file codage.bas